با گلخانه هوشمند خود با خیالی راحت به سفر بروید

				
					//Display ==========================================
#include "SSD1306Ascii.h"
#include "SSD1306AsciiWire.h"

#define OLED_I2C_ADDRESS 0x3C

SSD1306AsciiWire oled;

//Sensors ==========================================
#include "DFRobot_SHT20.h"
DFRobot_SHT20 sht20;

#include "DFRobot_VEML7700.h"
DFRobot_VEML7700 als;

const int AirValue = 830;   
const int WaterValue = 600;  

// WiFi UART Connection =================================
#include <SoftwareSerial.h>
#define ARD_RX_ESP_TX   4 // Arduino RX = ESP TX
#define ARD_TX_ESP_RX   7 // Arduino TX = ESP RX
SoftwareSerial EspSerial(ARD_RX_ESP_TX, ARD_TX_ESP_RX); 

#define ESP_AT_BAUD     9600  
#define ESP_RST_PIN     8

#include "WiFiEsp.h"

char ssid[] = "YOUR_SSID";            // your network SSID (name)
char pass[] = "YOUR_PASSWORD";        // your network password

// Initialize the Ethernet client object
WiFiEspClient client;

// IOT Platform ===================================
#define SERVER_NAME   "169.55.61.243" //"industrial.api.ubidots.com"
#define SERVER_PORT   (80)

unsigned long lastConnectionTime = 0;         // last time you connected to the server, in milliseconds
//const unsigned long postingInterval = 10000L; // delay between updates, in milliseconds
const unsigned long postingInterval = 600000L; // delay between updates, in milliseconds

//Relays =================================
#define FAN_RLY_PIN   5
#define HEATER_RLY_PIN  14

void setup(void)
{
  Serial.begin(9600);
  while (!Serial);
  
  pinMode(FAN_RLY_PIN,OUTPUT);
  pinMode(HEATER_RLY_PIN,OUTPUT);

  Wire.begin();  
  oled.begin(&Adafruit128x32, OLED_I2C_ADDRESS);
  oled.setFont(Adafruit5x7);

  oled.clear();
  oled.print(F("Booting ESP ... "));
  
  pinMode(ESP_RST_PIN, OUTPUT);
  //ESP RESET
  digitalWrite(ESP_RST_PIN, LOW);
  delay(50);
  digitalWrite(ESP_RST_PIN, HIGH);
  delay(2000); // to boot

  // initialize serial for ESP module
  EspSerial.begin(ESP_AT_BAUD);
  // initialize ESP module
  WiFi.init(&EspSerial);

  // check for the presence of the shield
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi module not present");
    // don't continue
    while (true);
  }
  oled.println(F("Done"));
  
  oled.print(F("Connecting ... "));
  // attempt to connect to WiFi network
  int status = WL_IDLE_STATUS;     // the Wifi radio's status
  while ( status != WL_CONNECTED) {
    Serial.print(F("Connecting to WPA SSID: "));
    Serial.println(ssid);
    // Connect to WPA/WPA2 network
    status = WiFi.begin(ssid, pass);
  }

  oled.println(F("Done"));
  
  oled.println(F("Initializing Sensors"));

  als.begin();   // Init
  sht20.initSHT20();                         // Init SHT20 Sensor
  delay(1000);
  sht20.checkSHT20();                        // Check SHT20 Sensor
}

void loop(void)
{
  float humd = sht20.readHumidity();         // Read Humidity
  float temp = sht20.readTemperature();      // Read Temperature
  float lux;
  als.getALSLux(lux);   // Get the measured ambient light value

  int soilMoistureValue = analogRead(A7);  //put Sensor insert into soil
  Serial.println(soilMoistureValue);
  int soilmoisturepercent = map(soilMoistureValue, AirValue, WaterValue, 0, 100);

  if(soilmoisturepercent >= 100)
  {
    soilmoisturepercent = 100;
  }
  else if(soilmoisturepercent <=0)
  {
    soilmoisturepercent = 0;
  }

  oled.clear(); // Clear screen
  oled.print("L:");
  oled.print(lux,2);
  oled.print(", T:");
  oled.print(temp,2);
  oled.println("°C");
  oled.print("H:");
  oled.print(humd,2);
  oled.print("%");
  oled.print(", S:");
  oled.print(soilmoisturepercent);
  oled.println("%");

  if(humd>60.0){
    digitalWrite(FAN_RLY_PIN,HIGH);
  }else{
    digitalWrite(FAN_RLY_PIN,LOW);  
  }

  if(temp<30.0){
    digitalWrite(HEATER_RLY_PIN,HIGH);
  }else{
    digitalWrite(HEATER_RLY_PIN,LOW);  
  }

  // if 10 seconds have passed since your last connection,
  // then connect again and send data
  if (millis() - lastConnectionTime > postingInterval) {
    oled.print("Sending Data ...");
    http_post(String(F("{\"Temp\":"))+ String(temp,6)+
              String(F(",\"Humid\":")) + String(humd,6)+
              String(F(",\"Lux\":")) + String(lux,6)+
              String(F(",\"Soil\":")) + String(soilmoisturepercent)+
              String("}"));
  }
  delay(1000);
}

void http_post( String postdata) {
  // close any connection before send a new request
  // this will free the socket on the WiFi module
  client.stop();
  
  if (client.connect(SERVER_NAME, SERVER_PORT)) 
  {
    // Sending the HTTP request
    client.println(("POST /api/v1.6/devices/garden/ HTTP/1.1"));
    client.println(F("Host: industrial.api.ubidots.com"));
    client.println(F("User-Agent: ESP8266/1.0"));
    client.println(F("X-Auth-Token: REPLACE_YOUR_TOKEN"));
    client.println(F("Content-Type: application/json"));
    client.print(F("Content-Length: "));
    client.println(String(postdata.length()));
    client.println(F("Connection: close"));
    client.println();
    client.println(postdata);

    // note the time that the connection was made
    lastConnectionTime = millis();
    
    // if there are incoming bytes available
    // from the server, read them and print them
    while (client.connected());
    while (client.available()) {
      char c = client.read();
      Serial.write(c);      // note the time that the connection was made
   }
    lastConnectionTime = millis();  
    Serial.println();
    Serial.println("Disconnecting from server...");
  } 
  else 
  {
   Serial.println(F("Connect failed"));
  }
}