دزدگیر خانه هوشمند

				
					//Display ==========================================
#include "SSD1306Ascii.h"
#include "SSD1306AsciiWire.h"

#define OLED_I2C_ADDRESS 0x3C

SSD1306AsciiWire oled;

//RGB LEDs ==========================================
#include <FastLED.h>
#define LED_PIN     16
#define NUM_LEDS    2
CRGB leds[NUM_LEDS];

//Sensors ==========================================
#include "DFRobot_SHT20.h"
DFRobot_SHT20 sht20;

#include "DFRobot_VEML7700.h"
DFRobot_VEML7700 als;

// GSM UART Connection =================================
#include <SoftwareSerial.h>
#define ARD_RX_GSM_TX   4 // Arduino RX = GSM TX
#define ARD_TX_GSM_RX   7 // Arduino TX = GSM RX
SoftwareSerial gsmSerial(ARD_RX_GSM_TX, ARD_TX_GSM_RX); 

#define GSM_AT_BAUD     9600  
#define GSM_PWR_PIN     9

//Pins =================================
#define MAGNET_PIN  2
#define PIR_PIN     A0
#define BUZZ_PIN    5

//Relay Module===================
#include "pca95xx.h"
#define RELAY_ADDR 0x73

void setup(void)
{
  Serial.begin(9600);
  while (!Serial);

  FastLED.addLeds<WS2812, LED_PIN, GRB>(leds, NUM_LEDS);

  Wire.begin();  
  oled.begin(&Adafruit128x32, OLED_I2C_ADDRESS);
  oled.setFont(Adafruit5x7);

  pca95xx_configure(RELAY_ADDR, PCA95XX_POL_DEFAULT_ALL, PCA95XX_OUT_ALL);
  pca95xx_out(RELAY_ADDR, 0xFF); // turn off all relays
  
  //Begin serial communication with Arduino and GSM Module
  gsmSerial.begin(9600);

  oled.clear();
  oled.print(F("Powering GSM ... "));

  pinMode(GSM_PWR_PIN,OUTPUT);
  //GSM POWER ON
  digitalWrite(GSM_PWR_PIN,LOW);
  delay(1000);
  digitalWrite(GSM_PWR_PIN,HIGH);
  
  oled.println(F("Done"));

  oled.print(F("Initing GSM ... "));
  delay(3000);
  gsm_send_serial("AT"); //Once the handshake test is successful, it will back to OK
  delay(300);
  gsm_read_serial();
  delay(1000);
  gsm_read_serial();
  delay(1000);
  gsm_read_serial();
  delay(1000);
  gsm_read_serial();
  delay(1000);
  gsm_read_serial();
  delay(1000);
  
  gsm_send_serial("ATE1"); 
  delay(300);
  gsm_send_serial("AT+CNMI=2,2,0,0,0"); 
  delay(300);
  gsm_send_serial("AT+CMGF=1");         //Set the module to SMS mode
  delay(300);
  
  gsm_send_serial("AT+CSMP=17,167,2,17");  //Set SMS Text Mode Parameters
  delay(300);
  gsm_send_serial("AT+CSCS=\"GSM\""); //Select TE Character Set
  delay(300);

  gsmSerial.println("AT+CMGS=\"YOUR_PHONE_NUMBER\"");  //Your phone number don't forget to include your country code, example +989123456789"
  delay(300);
  gsmSerial.print("HELLO");       //This is the text to send to the phone number, don't make it too long or you have to modify the SoftwareSerial buffer
  gsmSerial.print((char)0x1A);// (required according to the datasheet)
  gsm_read_serial();
  delay(1000);
  gsm_read_serial();
  delay(1000);
  gsm_read_serial();
  
  oled.println(F("Done"));

  oled.println(F("Initializing Sensors"));
  pinMode(BUZZ_PIN, OUTPUT);
  pinMode(MAGNET_PIN,INPUT_PULLUP);
  pinMode(PIR_PIN,INPUT);
  
  sht20.initSHT20();                         // Init SHT20 Sensor
  delay(1000);
  sht20.checkSHT20();                        // Check SHT20 Sensor
}

char str[15];
int idx=0;
bool cmdFound= false;

bool tvOn = false;
bool fanOn = false;
bool lightOn = false;

bool toggle = true;

void loop(void)
{
  float humd = sht20.readHumidity();         // Read Humidity
  float temp = sht20.readTemperature();      // Read Temperature
  float lux;
  als.getALSLux(lux);   // Get the measured ambient light value
  
  int doorOpened = digitalRead(MAGNET_PIN); // 0 close - 1 open
  int motionDetected = digitalRead(PIR_PIN);

  findCmd();
  if(cmdFound)
  {
    checkCmd();
    updateRelay();
    cmdFound=false;
    idx=0;
  }
 
  oled.clear(); // Clear screen
  if(motionDetected || doorOpened){
    if(toggle){
      analogWrite(BUZZ_PIN, 32);
      leds[0] = CRGB(255, 0, 0);
      leds[1] = CRGB(0, 0, 255);
      FastLED.show();
      toggle = false;
    }else{
      analogWrite(BUZZ_PIN, 250);
      leds[0] = CRGB(0, 0, 255);
      leds[1] = CRGB(255, 0, 0);
      FastLED.show();
      toggle = true;
    }
    if(motionDetected) oled.println("MOTION DETECTED!");
    if(doorOpened) oled.println("DOOR OPENED!");
  }else{
    analogWrite(BUZZ_PIN, 0);
    leds[0] = CRGB(0, 255, 0);
    leds[1] = CRGB(0, 255, 0);
    FastLED.show();
    oled.print("L:");
    oled.print(lux,2);
    oled.print(", T:");
    oled.print(temp,2);
    oled.println("°C");
    oled.print("H:");
    oled.print(humd,2);
    oled.println("% ");
    oled.println("Fan   Light  TV ");
    fanOn ? oled.print("ON     ") : oled.print("OFF    ");
    lightOn ? oled.print("ON    ") : oled.print("OFF   ");
    tvOn ? oled.println("ON  ") : oled.println("OFF ");
  }
  
  delay(500);
}

void gsm_read_serial()
{
  while(gsmSerial.available()) 
  {
    Serial.write(gsmSerial.read());
  }
}

void gsm_send_serial(String command) {
  Serial.println("Send ->: " + command);
  gsmSerial.println(command);
  long wtimer = millis();
  while (wtimer + 3000 > millis()) {
    while (gsmSerial.available()) {
      Serial.write(gsmSerial.read());
    }
  }
  Serial.println();
}

void findCmd() 
{
  while(gsmSerial.available()) 
  {
    if(gsmSerial.find("#A."))
    {
      while (gsmSerial.available()) 
      {
        char inChar=gsmSerial.read();
        str[idx++]=inChar;
        if(inChar=='*')
        {
          cmdFound=1;
          return;
        } 
      } 
    }
  }
}

void checkCmd()
{
   if(!(strncmp(str,"tv on",5)))
   {
     tvOn = true;
   }  
   else if(!(strncmp(str,"tv off",6)))
   {
     tvOn = false;
   }
   else if(!(strncmp(str,"fan on",6)))
   {
     fanOn = true;
   }
   else if(!(strncmp(str,"fan off",7)))
   {
     fanOn = false;
   }
   else if(!(strncmp(str,"light on",8)))
   {
     lightOn = true;
   }
   else if(!(strncmp(str,"light off",9)))
   {
     lightOn = false;
   } 
   else if(!(strncmp(str,"all on",6)))
   {
     tvOn = true;
     fanOn = true;
     lightOn = true;
   }
   else if(!(strncmp(str,"all off",7)))
   {
     tvOn = false;
     fanOn = false;
     lightOn = false;
   }
}

void updateRelay()
{
  uint8_t state = 0xFF;

  if(fanOn) state &= 0xFE;
  if(lightOn) state &= 0xFD;
  if(tvOn) state &= 0xFB;
  
  pca95xx_out(RELAY_ADDR, state);
}