ردیاب خودرو بسازیم

				
					#include <TinyGPSPlus.h>
#include <SoftwareSerial.h>
#include <FastLED.h>

#define GSM_TX_PIN 4
#define GSM_RX_PIN 7
#define GSM_PWR_PIN 9

#define GPS_RST_PIN 8

#define LED_PIN     16
#define NUM_LEDS    2

// The TinyGPS++ object
TinyGPSPlus gps;
//Create software serial object to communicate with SIM800
SoftwareSerial serialGSM(GSM_TX_PIN,GSM_RX_PIN);

CRGB leds[NUM_LEDS];

void setup() {
  // Powering Up ...
  pinMode(GSM_PWR_PIN,OUTPUT);
  pinMode(GPS_RST_PIN,OUTPUT);
  //GPS reset
  digitalWrite(GPS_RST_PIN,LOW);
  //GSM Power ON
  digitalWrite(GSM_PWR_PIN,LOW);
  delay(1000);
  digitalWrite(GPS_RST_PIN,HIGH);
  digitalWrite(GSM_PWR_PIN,HIGH);

  FastLED.addLeds<WS2812, LED_PIN, GRB>(leds, NUM_LEDS);
  leds[0] = CRGB(255, 255, 255);
  leds[1] = CRGB(255, 255, 255);
  FastLED.show();
  
  //Begin serial communication with Arduino and GPS
  Serial.begin(9600);
  //Begin serial communication with Arduino and GSM
  serialGSM.begin(9600);
  delay(5000);
  serialGSM.println("AT"); //Once the handshake test is successful, it will back to OK
  delay(5000);
  
  leds[0] = CRGB(0, 0, 0);
  leds[1] = CRGB(0, 0, 0);
  FastLED.show();
}
long lastSendTime = 0;
void loop() {
  // reading GPS data from UART
  while (Serial.available() > 0){
    if (gps.encode(Serial.read())){
      if (gps.location.isValid()){
          leds[1] = CRGB(0, 255, 0);
          FastLED.show();
          if(lastSendTime + 60000 < millis()){
            lastSendTime = millis();
            leds[0] = CRGB(0, 0, 255);
            FastLED.show();
            // sending location
            gsm_http_post(String("{\"position\":{\"lat\":")+String(gps.location.lat(),6)+String(",\"lng\":")+String(gps.location.lng(),6)+String("}}"));
            leds[0] = CRGB(0, 255, 0);
            FastLED.show();
         }
      }else{
        // location is not valid
        leds[0] = CRGB(0, 0, 0);
        leds[1] = CRGB(0, 0, 255);
        FastLED.show();
      }
    }
  }
  
  if (millis() > 15000 && gps.charsProcessed() < 10)
  {
      leds[0] = CRGB(255, 0, 0);
      leds[1] = CRGB(255, 0, 0);
      FastLED.show();
      // No GPS detected: check wiring.
      while(true);
  }
}


void gsm_http_post( String postdata) {
/* Use AT+QIDNSIP=0 to use the IP address to establish TCP/UDP session, while AT+QIDNSIP=1 is use the domain name to establish TCP/UDP session */
  gsm_send_serial(F("AT+QIDNSIP=1"), 3000);
/* Use AT+QIOPEN="TCP","industrial.api.ubidots.com","80" to connect to a TCP server. If return "CONNECT OK" means successfully connected to the remote server */
  gsm_send_serial(F("AT+QIOPEN=\"TCP\",\"industrial.api.ubidots.com\",\"80\""), 10000);// Start the connection to Ubidots
/* AT+QISEND, send data to server, ">" from the UART indicates the following input data is considered as data to be send. After receiving ">", input data (TEST),
the maximum length of the data is 1460, the data beyond 1460 will be omitted. Then use <CTRL+Z> to send data. When receive SEND OK means the data has been sent */
  gsm_send_serial(F("AT+QISEND"), 1000);// Start to send data to remote server
  gsm_send_serial(F("POST /api/v1.6/devices/tracker/ HTTP/1.1"), 100);
  gsm_send_serial(F("Host: industrial.api.ubidots.com"), 100);
  gsm_send_serial(F("X-Auth-Token: REPLACE_YOUR_TOKEN"), 100);
  gsm_send_serial(F("Content-Type: application/json"), 100);
  gsm_send_serial("Content-Length: "+String(postdata.length()), 100);
  gsm_send_serial(F("Connection: close"), 100);
  serialGSM.println();
  gsm_send_serial(postdata, 100);
  serialGSM.println();
  serialGSM.println((char)26); // Sending the HTTP request
/* Use AT+QISACK to query whether all the data has been sent out */
  gsm_send_serial(F("AT+QISACK"), 3000);
  delay(7000); // Waiting for a reply. Important! tweak this time depending on the latency of your mobile Internet connection
  gsm_send_serial(F("AT+QICLOSE"), 1000);
}

void gsm_send_serial(String command, long to) {
  serialGSM.println(command);
  long wtimer = millis();
  while (wtimer + to > millis()) {
    while (serialGSM.available()) {
      serialGSM.read();
    }
  }
}