پارکینگ هوشمند

				
					//RGB LEDs ==========================================
#include <FastLED.h>
#define LED_PIN     16
#define NUM_LEDS    2
CRGB leds[NUM_LEDS];

//Sensor ==========================================
#define echoPin 15 // Echo of HC-SR04
#define trigPin 6 // Trig of HC-SR04

long duration; // variable for the duration of sound wave travel
int distance; // variable for the distance measurement
int maxDistance = 200;
bool lastState;

// WiFi UART Connection =================================
#include <SoftwareSerial.h>
#define ARD_RX_ESP_TX   4 // Arduino RX = ESP TX
#define ARD_TX_ESP_RX   7 // Arduino TX = ESP RX
SoftwareSerial EspSerial(ARD_RX_ESP_TX, ARD_TX_ESP_RX); 

#define ESP_AT_BAUD     9600  
#define ESP_RST_PIN     8

#include "WiFiEsp.h"

char ssid[] = "YOUR_SSID";            // your network SSID (name)
char pass[] = "YOUR_PASSWORD";        // your network password

// Initialize the Ethernet client object
WiFiEspClient client;

// IOT Platform ===================================
#define SERVER_NAME   "169.55.61.243" //"industrial.api.ubidots.com"
#define SERVER_PORT   (80)

unsigned long lastConnectionTime = 0;         // last time you connected to the server, in milliseconds
const unsigned long postingInterval = 10000L; // delay between updates, in milliseconds
//const unsigned long postingInterval = 600000L; // delay between updates, in milliseconds


void setup(void)
{
  Serial.begin(9600);
  while (!Serial);
  
  pinMode(trigPin, OUTPUT); // Sets the trigPin as an OUTPUT
  pinMode(echoPin, INPUT); // Sets the echoPin as an INPUT

  FastLED.addLeds<WS2812, LED_PIN, GRB>(leds, NUM_LEDS);
  
  pinMode(ESP_RST_PIN, OUTPUT);
  //ESP RESET
  digitalWrite(ESP_RST_PIN, LOW);
  delay(50);
  digitalWrite(ESP_RST_PIN, HIGH);
  delay(2000); // to boot

  // initialize serial for ESP module
  EspSerial.begin(ESP_AT_BAUD);
  // initialize ESP module
  WiFi.init(&EspSerial);

  // check for the presence of the shield
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi module not present");
    // don't continue
    while (true);
  }

  // attempt to connect to WiFi network
  int status = WL_IDLE_STATUS;     // the Wifi radio's status
  while ( status != WL_CONNECTED) {
    Serial.print(F("Connecting to WPA SSID: "));
    Serial.println(ssid);
    // Connect to WPA/WPA2 network
    status = WiFi.begin(ssid, pass);
  }
  Serial.println("You're connected to the network");
}

void loop(void)
{
  // Clears the trigPin condition
  digitalWrite(trigPin, LOW);
  delayMicroseconds(2);
  // Sets the trigPin HIGH (ACTIVE) for 10 microseconds
  digitalWrite(trigPin, HIGH);
  delayMicroseconds(10);
  digitalWrite(trigPin, LOW);
  // Reads the echoPin, returns the sound wave travel time in microseconds
  duration = pulseIn(echoPin, HIGH);
  // Calculating the distance
  distance = duration * 0.034 / 2; // Speed of sound wave divided by 2 (go and back)
  
  // Displays the distance on the Serial Monitor
  Serial.print("Distance: ");
  Serial.print(distance);
  Serial.println(" cm");

  bool occupied = false;
  if(distance < (maxDistance - 20)){
    occupied = true;
    leds[0] = CRGB(255, 0, 0);
    leds[1] = CRGB(255, 0, 0);
    FastLED.show();
  }else{
    leds[0] = CRGB(0, 255, 0);
    leds[1] = CRGB(0, 255, 0);
    FastLED.show();
  }

  // if postingInterval seconds have passed since your last connection,
  // then connect again and send data
  if (millis() - lastConnectionTime > postingInterval || lastState != occupied) {
    Serial.println("Sending Data ...");
    lastState = occupied;
    http_post(String(F("{\"Car\":"))+ String(maxDistance - distance)+
              String(F(",\"Occ\":")) + String(occupied)+
              String("}"));
  }
  
  delay(1000);
}

void http_post( String postdata) {
  // close any connection before send a new request
  // this will free the socket on the WiFi module
  client.stop();
  
  if (client.connect(SERVER_NAME, SERVER_PORT)) 
  {
    Serial.println("Sending Req ...");
    // Sending the HTTP request
    client.println(("POST /api/v1.6/devices/parking/ HTTP/1.1"));
    client.println(F("Host: industrial.api.ubidots.com"));
    client.println(F("User-Agent: ESP8266/1.0"));
    client.println(F("X-Auth-Token: REPLACE_YOUR_TOKEN"));
    client.println(F("Content-Type: application/json"));
    client.print(F("Content-Length: "));
    client.println(String(postdata.length()));
    client.println(F("Connection: close"));
    client.println();
    client.println(postdata);
    delay(100);
    
    Serial.println("Waiting Res ...");
    // if there are incoming bytes available
    // from the server, read them and print them
    while (client.connected());
    while (client.available()) {
      char c = client.read();
      Serial.write(c);      // note the time that the connection was made
   }
    lastConnectionTime = millis();  
    Serial.println();
    Serial.println("Disconnecting from server...");
  } 
  else 
  {
   Serial.println(F("Connect failed"));
  }
}